Die Computerkonfiguration hat bei dieser Richtlinien Vorrang, falls an beiden Stelle eine Einstellung vorgenommen wurde. Bei der Aktivierung dieser Richtlinie werden erst die Scripts komplett zu Ende ausgeführt, bevor die Explorer-Schnittstelle gestartet wird. Dadurch kann gewährleistet werden, daß bestimmte Abhängigkeiten und/oder Netzwerkressourcen zum Zeitpunkt des Desktopaufbaus auf jeden Fall vorhanden sind.
 
Wichtig ist,  unter "Benutzerkonfiguration / Administrative Vorlagen / System" darf die Befehlszeilenaufforderung nicht abgeschaltet sein, weil sonst keine Batchdateien ausgeführt werden können.
 
Will man für Benutzer NETLOGON-Skripts anwenden, wenn sie an einer NT-Station arbeiten und für 2000/XP-Rechner bei denselben Usern die GPO-Technik nutzen, so kann man das NETLOGON-Skript klassisch den Benutzern zuweisen und im Skript selbst testen, welches System der Client ausführt. Ist es ein 2000- oder XP-Rechner, so wird das Skript beendet. Das geht aber nur mit einem Zusatzprogramm (gettype.exe aus dem Resource Kit), das über Errorlevel abgefragt wird.
 
 
 
Anmeldescripte – Beispiele
 
---------------- Benutzer- / Gruppenabfrage, Zuweisung Drucker -------------------
@echo off
rem benötigte Tools: con2prt.exe und ifmember.exe aus dem ResKit
rem da das con2prt immer im freien Download war, kann man es auch unter
rem http://www.gruppenrichtlinien.de/tools/con2prt.exe herunterladen

 
rem [ COMMON, fuer alle Benutzer gueltig ]
 
rem **  Mapping der Laufwerke, die allen zur Verfuegung stehen **
net use m: \\server\freigabe1 /persistent:no
net use n: \\server\freigabe2 /persistent:no
 
rem [ Auswahl, des Sprungziels nach Gruppenzugehoerigkeit ]
 
rem **  Auswahl der Gruppe ueber ifmember.exe, wenn Uebereinstimmung, **
rem **  dann Sprungziel Auswahl **
 
\\SERVER\netlogon\ifmember Verwaltung
if errorlevel 1 goto GR_VERWALTUNG
 
rem ** weitere Abfragen möglich **
rem **  Abgeschlossen wird das Ganze durch ein GOTO END, damit bei keiner Übereinstimmung **
rem **  der Gruppenzugehörigkeit, keine weitere Aktiion durchgeführt wird.
goto END
 
rem [ Sprungziel Verwaltung ]
 
:GR_VERWALTUNG
rem **  Drucker im Buero/Verwaltung, es wird noch kein Standarddrucker zugewiesen **
rem **  innerhalb dieser Gruppe kann widerum nach Benutzernamen oder Computernamen **
rem **  unterschieden werden **
 
rem **  diese Drucker stehen allen Mitgleidern zur Verfügung **
rem **  con2prt Optionen: /c = connect; /cd= connect default; /f = lösche vorhandene
%logonserver%\netlogon\con2prt /c "\\server\HPLaserjet1"
%logonserver%\netlogon\con2prt /c "\\server\HPLaserJet2"
 
rem **  durch den Parameter /i wird nicht in Klein-/Großschreibung unterschieden **
if /i %username%==Dieter.Meier goto Dieter
if /i %username%==Heiner.Geier goto Heiner
 
:DIETER
%logonserver%\netlogon\con2prt /cd "\\server\HPLaserJet3"
%logonserver%\netlogon\con2prt /c "\\server\HPLaserJet4"
goto END
 
: HEINER
%logonserver%\netlogon\con2prt /c "\\server\HPLaserJet3"
%logonserver%\netlogon\con2prt /cd "\\server\HPLaserJet4"
goto END
 
:END
 
---------------- EOF: Benutzer- / Gruppenabfrage, Zuweisung Drucker -------------------
 
 
---------------- Druckerzuweisung per Computername -------------------
@echo off
rem ** benötigtes Tool: con2prt.exe aus dem ResKit, oder dem ZAK
rem ** da das con2prt immer im freien Download war, kann man es auch unter
rem ** http://www.gruppenrichtlinien.de/tools/con2prt.exe herunterladen
rem ** Sortierung der Drucker z.B.: nach Räumen, kann allerdings nur
rem ** funktionieren, wenn für eine einheitliche Namensgebung Sorge getragen wurde
rem ** Beispiel: die Räume heissen: 401, 402, 403,
rem ** die PC´s entspreched 401-01, 401-02 ...402-01, 402-06 etc ...
 
rem ** Allgemeine Hinweise:
rem ** Computernamen ausfindig machen und Drucker wählen:
rem ** mit der Anweisung ":~0,3" werden nur die ersten 3 Zeichen
rem ** der Variable %computername% ausgewertet
 
rem ** Beispiele, COMPUTERNAME = 123456789ABCDE0:
rem ** nur die ersten 5 Zeichen auswerten
rem ** %computername:~0,5% bzw.
rem ** %computername:~,5% geben das Ergebnis "12345"
 
rem ** die ersten 7 Zeichen auslassen, dann die nächsten 5 auswerten
rem ** %computername:~7,5% gibt das Ergebnis "89ABC"
 
rem ** die ersten 7 Zeichen auslassen, dann alle berücksichtigen
rem ** %computername:~7% gibt das Ergebnis "89ABCDEF0"
 
 
rem ** erst mal alle vorh. Drucker löschen, damit keine falschzugeordneten Drucker
rem ** mehr mit den Rechnern verbunden sind
con2prt /f
 
rem ** jetzt die Abfrage nach den Computernamen,
rem ** mit /i wird Groß-/Kleinschreibung ignoriert
if /i %computername:~0,3%==401 goto Drucker1
if /i %computername:~0,3%==402 goto Drucker2
if /i %computername:~0,3%==403 goto Drucker3
 
goto END
 
:Drucker1
rem ** jetzt Standarddrucker für diesen Raum festlegen
con2prt /cd \\server\druckerraum1
goto end
 
:Drucker2
con2prt /cd \\server\druckerraum2
goto end
 
:Drucker3
con2prt /cd \\server\druckerraum3
goto end
 
:end
---------------- EOF: Druckerzuweisung per Computername -------------------

---------------- IP Adresse und Subnetz als Variable setzen -------------------
rem ** Hiermit erstellen wir uns 2 eigene Variablen => %ipadress% und %netid% die dann **
rem ** im weiteren Verlauf des Scriptes zur Abfrage benutzt werden können **
 
for /f "Tokens=2 Delims=[] skip=1" %%i in ('ping -n 1 %computername%') do set IPAdress=%%i
for /f "Tokens=1,2,3 Delims=." %%a in ('echo %IPAdress%') do set NetID=%%a.%%b.%%c
 
---------------- EOF: IP Adresse als Variable setzen -------------------

---------------- OU als Variable setzen -------------------
rem ** Hiermit erstellen wir uns eine eigene Variable => %aktuelleOU% die dann **
rem ** im weiteren Verlauf des Scriptes zur Abfrage benutzt werden kann **
rem ** dsquery.exe ist beim 2003 Server dabei
rem ** gleiche Abfrage liesse sich auch für den Benutzer erstellen.
 
for /f "Tokens=2 Delims=," %%i in ('dsquery computer -name %computername%') do set aktuelleOU=%%i
 
---------------- EOF: OU als Variable setzen -------------------


(c) 2003 - heute, Mark Heitbrink, weitere Informationen unter WebSite-Info\Copyright