Anmelde Skript: Druckerzuweisung per Computername

Autor: Mark Heitbrink - vom 09.01.2013 - Kategorie(n): Skripte

----- Druckerzuweisung per Computername --------
@echo off
rem benötigtes Tool: con2prt.exe aus dem ResKit, oder dem ZAK
rem da das con2prt immer im freien Download war, kann man es auch unter
rem www.gruppenrichtlinien.de/tools/con2prt.exe herunterladen
rem Sortierung der Drucker z.B.: nach Räumen, kann allerdings nur 
rem funktionieren, wenn für eine einheitliche Namensgebung Sorge getragen wurde
rem Beispiel: die Räume heissen: 401, 402, 403, 
rem die PC´s entspreched 401-01, 401-02 ...402-01, 402-06 etc ...
 
rem Allgemeine Hinweise:
rem Computernamen ausfindig machen und Drucker wählen:
rem mit der Anweisung ":~0,3" werden nur die ersten 3 Zeichen 
rem der Variable %computername% ausgewertet
 
rem Beispiele, COMPUTERNAME = 123456789ABCDE0:
rem nur die ersten 5 Zeichen auswerten
rem %computername:~0,5% bzw.
rem %computername:~,5% geben das Ergebnis "12345"
 
rem die ersten 7 Zeichen auslassen, dann die nächsten 5 auswerten
rem %computername:~7,5% gibt das Ergebnis "89ABC"
 
rem die ersten 7 Zeichen auslassen, dann alle berücksichtigen
rem %computername:~7% gibt das Ergebnis "89ABCDEF0"
 
 
rem erst mal alle vorh. Drucker löschen, damit keine falschzugeordneten Drucker
rem mehr mit den Rechnern verbunden sind
con2prt /f
 
rem jetzt die Abfrage nach den Computernamen, 
rem mit /i wird Groß-/Kleinschreibung ignoriert
if /i %computername:~0,3%==401 goto Drucker1 
if /i %computername:~0,3%==402 goto Drucker2 
if /i %computername:~0,3%==403 goto Drucker3 
 
goto END
 
:Drucker1
rem jetzt Standarddrucker für diesen Raum festlegen
con2prt /cd \\server\druckerraum1
goto end
 
:Drucker2
con2prt /cd \\server\druckerraum2
goto end
 
:Drucker3
con2prt /cd \\server\druckerraum3
goto end
 
:end
----- EOF: Druckerzuweisung per Computername -----